*========================nastaveni
clear
set more off

*path w3
global DATA ="C:\WORK\SHARE\DATA - rel 7.0.0"

tempfile deti1

*========================
*========================spojeni vzdelani reportovanych v ruznych vlnach v gv_isced do jednoho datasetu
*========================
*ve 3 vlne neni zadny refreshment, proto staci spojit 2., 4., 5. 6. a 7 vlnu 

foreach v in 1 2 4 5 6 7 {
cd "$DATA"
use "sharew`v'_rel7-0-0_ALL_datasets_stata\sharew`v'_rel7-0-0_ch", clear

*ponechani prejmenovani a uprava potrebnych promennych 
rename ch001_ 	PocDeti
	forvalues i = 1(1)15 {
		rename ch005_`i' PohlDite_`i'
	}
replace PocDeti=. if PocDeti==-2
keep mergeid PocDeti PohlDite_*
sort mergeid 

*spojeni ruznych vln modulu vzdelani
if `v'!=1 merge 1:1 mergeid using `deti1', update
if `v'!=1 drop _merge

*ulozeni
sort mergeid 
save `deti1', replace
}


*vlna 7 - deti v modulu rc
use "sharew7_rel7-0-0_ALL_datasets_stata\sharew7_rel7-0-0_rc", clear

*ponechani prejmenovani a uprava potrebnych promennych 
rename rc023_ 	PocDeti
	forvalues i = 1(1)15 {
		rename rc026_`i' PohlDite_`i'
	}
keep mergeid PocDeti PohlDite_*

*spojeni ruznych vln modulu vzdelani
sort mergeid 
merge 1:1 mergeid using `deti1', update
drop _merge

*ulozeni
sort mergeid

*========================
*========================prirazeni pocet deti a pohlavi PARTNEROVI (udaj je vyplnovan jenom jednym z partneru)
*========================
gen str id_part=substr(mergeid,1,9)

sort id_part PocDeti
replace PocDeti=PocDeti[_n-1] if PocDeti==. & id_part==id_part[_n-1]
forvalues i = 1(1)15 {
	replace PohlDite_`i'=PohlDite_`i'[_n-1] if PohlDite_`i'==. & id_part==id_part[_n-1]
}