*PRIKLAD PRACE S SHARE DATY.		
*Syntax ukaze zakladni procedury pri praci s daty vyzkumu SHARE (selekci, pripojovani modulu) a dale priklady zakladnich operaci s promennymi (labely, rekodovani, filtr aj.) a analyticke vystupy (frekvence, t-test, anova).		
*Datove soubory: 	easySHARE_rel1-0-0.sav (Centerdata - úvodní stránka vpravo - "easySHARE_rel2-0-0.zip")	
		sharew4_rel1-1-1_ph.sav (Centerdata - "Wave 4" - "PH module" - "spss" - "sharew4_rel1-1-1_ph.zip")
		sharew4_rel1-1-1_ac.sav (Centerdata - "Wave 4" - "AC module" - "spss" - "sharew4_rel1-1-1_ac.zip")
		sharew4_rel1-1-1-gv_health.sav (Centerdata - "Wave 4" - "Generated Variables" - "Health" - "spss" - "sharew4_rel1-1-1_gv_health.zip")
*Aktualizace: 15. 6. 2015.		
		
		
*1. OTEVRENI SOUBORU		
  - nejprve nutno stazena data odzipovat a umistit ve slozce (napr. C:\SHARE)		
  - pote mozno spustit nasledujici prikaz.		
GET 		
  FILE='C:\SHARE\easySHARE_rel2-0-0.sav'. 		
DATASET NAME easy_w4 WINDOW=FRONT.		
		
*2. VYBRAT JEN DATA ZE 4. VLNY A ULOZIT JAKO NOVY DATASET.		
FREQUENCIES wave.		
SELECT IF wave=4.		
exe.		
*kontrola pocet respondentu 4.vlny N=58489.		
FREQUENCIES wave.		
		
sort cases by mergeid.		
SAVE OUTFILE='C:\SHARE\easySHARE_w4.sav'		
  /COMPRESSED.		
		
*3. NADEFINOVANI CHYBEJICICH HODNOT, TEDY MISSING VALUES		
  - v datech easySHARE maji missing values zaporne hodnoty (v rozmezi -15 az -1).		
MISSING VALUES int_month to income_pct_w4 (-15 thru -1).		
		
*4. PRIPOJENI PROMENNYCH "ac035d8", "ac035d9" a "ac035d10" z modulu AC		
 - pozn. zneni otazky: Vykonaval/a jste v poslednich 12 mesicich nekterou z aktivit? 		
	8. Cetba knih, casopisu nebo novin 	
	9. Lusteni krizovek, ciselnych hadanek, hrani stolnich her nebo sudoku	
	10. Hrani karet nebo her jako sachy.	
	
GET 		
  FILE='C:\SHARE\sharew4_rel1-1-1_ac.sav'. 		
DATASET NAME modulAC WINDOW=FRONT.		
sort cases by mergeid.		
		
MATCH FILES /FILE=*		
/keep=mergeid ac035d8 ac035d9 ac035d10.		
exe.		
FREQUENCIES ac035d8 ac035d9 ac035d10.		
MISSING VALUES ac035d8 ac035d9 ac035d10 (-2, -1).		
FREQUENCIES ac035d8 ac035d9 ac035d10.		
		
dataset activate easy_w4.		
MATCH FILES /FILE=*		
  /TABLE='modulAC'		
  /BY mergeid.		
EXECUTE.		
DATASET close modulAC.		
dataset activate easy_w4.		
		
*5. PRIPOJENI PROMENNYCH Z BATERIE OTAZEK "ph006" z modulu PH		
 - pozn. zneni otazky: Rekl Vam uz nekdy lekar, ze trpite v soucasne dobe nekterou z choro na karte c. 7?		
	1. Srdecni infarkt vcetne infarktu myokardu, tromboza srdecnich cev, angina pectoris nebo jine srdecni choroby vcetne selhavani srdecni cinnosti	
	2. Vysoky krevni tlak	
	3. Vysoka hladina cholesterolu	
	4. Mrtvice nebo poruchy prokrveni mozku	
	5. Cukrovka nebo vysoke hodnoty cukru	
	6. Chronicka onemocneni plic jako chronicka bronchitida nebo rozedma plic	
	7. Astma	
	8. Artritis vcetne osteoartritidy nebo revmatismu	
	9. Osteoporosis	
	10. Rakovina nebo zhoubny tumor, vcetne leukemie a rakoviny lymfatickych zlaz, s vyjimkou mensich onemocneni rakovinou kuze	
	11. Zaludecni vred, vred dvanacterniku	
	12. Parkinsonova nemoc	
	13. Sedy zakal	
	14. Zlomenina kycelniho krcku nebo kycle	
	15. Jine zlomeniny	
	16. Alzheimerova choroba, demence, organicke onemocneni mozku, senilita, nebo jine vazne poskozeni pameti	
	17. Benigni nador	
	96. Nic z jmenovaneho	
	97. Jine nemoci, ktere nebyly uvedeny	.
GET 		
  FILE='C:\SHARE\sharew4_rel1-1-1_ph.sav'. 		
DATASET NAME modulPH WINDOW=FRONT.		
sort cases by mergeid.		
		
MATCH FILES /FILE=*		
/keep=mergeid ph006d1 to ph006dot.		
exe.		
FREQUENCIES ph006d1 to ph006dot.		
MISSING VALUES ph006d1 to ph006dot (-2, -1).		
FREQUENCIES ph006d1 to ph006dot.		
		
dataset activate easy_w4.		
MATCH FILES /FILE=*		
  /TABLE='modulPH'		
  /BY mergeid.		
EXECUTE.		
DATASET close modulPH.		
dataset activate easy_w4.		
		
*5. PRIPOJENI PROMENNE "phactiv" z tzv. GENERATED VARIABLES		
 - pozn. tato otazka je zalozena na otazkach "br015_" a "br016_"		
zneni otazky br015_: Jak casto vykonavate namahavou telesnou cinnost (sport, fyzicky namahave prace v domacnosti nebo v zamestnani)?		
	1. Vice nez jednou tydne	
	2. Jednou tydne	
	3. Jednou az trikrat za mesic	
	4. V podstate nikdy	
zneni otazky br016_: Jak casto vykonavate stredne namahavou cinnost (prace na zahrade, myti auta, prochazka)?		
	1. Vice nez jednou tydne	
	2. Jednou tydne	
	3. Jednou az trikrat za mesic	
	4. V podstate nikdy.	
		
GET 		
  FILE='C:\SHARE\sharew4_rel1-1-1_gv_health.sav'. 		
DATASET NAME modulGV_health WINDOW=FRONT.		
sort cases by mergeid.		
		
MATCH FILES /FILE=*		
/keep=mergeid phactiv.		
exe.		
FREQUENCIES phactiv.		
MISSING VALUES phactiv (-2, -1).		
FREQUENCIES phactiv.		
		
dataset activate easy_w4.		
MATCH FILES /FILE=*		
  /TABLE='modulGV_health'		
  /BY mergeid.		
EXECUTE.		
DATASET close modulGV_health.		
dataset activate easy_w4.		
SAVE OUTFILE='C:\SHARE\easySHARE_w4.sav'		
  /COMPRESSED.		
		
		
*6. JEDNODUCHE OPERACE S DATY.		
*vytvoreni nove promenne rekodovanim stavajici - napr. vytvoreni promenne "pamet" (hodnoty: 1, 2, 3) na zaklade promenne recall_2 (Kognitivini test - na kolik slov z 10 si dokazal respondent zpetne vzpomenout, skala 0-10). 		
RECODE recall_2 (0,1,2=1) (3,4,5,6=2) (7,8,9,10=3) (sysmis=sysmis) into pamet.		
exe.		
*kontrola, zda probehl recode spravne.		
CROSSTABS recall_2 by pamet.		
		
*olabelovani nove promenne.		
VARIABLE LABELS pamet "Pamet respondenta".		
VALUE LABELS pamet		
1 "spatna pamet"		
2 "prumerna pamet"		
3 "vyborna pamet".		
		
*frekvence nove promenne.		
FREQUENCIES pamet.		
		
		
*7. ZAKLADNI VYSTUPY A TESTY PROMENNYCH.		
*KONTINGENCNI TABULKY.		
*porovnani zastoupeni jednotlivych typu pameti podle pohlavi - i s adjustovanymi rezidui.		
CROSSTABS		
  /TABLES=pamet by female		
  /FORMAT=AVALUE TABLES		
  /CELLS=COUNT ROW  ASRESID		
  /COUNT ROUND CELL.		
		
*zakladni vystupy - porovnani zastoupeni jednotlivych typu pameti v jednotlivych statech - i s adjustovanymi rezidui.		
CROSSTABS		
  /TABLES=country BY pamet		
  /FORMAT=AVALUE TABLES		
  /CELLS=COUNT ROW ASRESID 		
  /COUNT ROUND CELL.		
		
*porovnani zastoupeni jednotlivych typu pameti v jednotlivych statech podle pohlavi - radkova procenta.		
CROSSTABS		
  /TABLES=country BY pamet by female		
  /FORMAT=AVALUE TABLES		
  /CELLS=COUNT ROW  		
  /COUNT ROUND CELL.		
		
*T-TEST.		
*otestovani vlivu pravidelnych mentalnich aktivit (napr. lusteni krizovek - ac035d9) na vysledky testu pameti (t-test - independent sample test).		
T-TEST GROUPS=ac035d9(1 0) 		
  /MISSING=ANALYSIS 		
  /VARIABLES=recall_2 		
  /CRITERIA=CI(.95).		
		
*otestovani vlivu fyzicke aktivity na vysledky testu pameti (t-test - independent sample test).		
T-TEST GROUPS=phactiv (1 0) 		
  /MISSING=ANALYSIS 		
  /VARIABLES=recall_2 		
  /CRITERIA=CI(.95).		
		
*RECODE, FILTR, ANOVA.		
*vytvoreni desetiletych vekovych kategorii a nasledne vyfiltrovani respondentu ve veku 50-89 let.		
fre age.		
recode age (lowest thru 49.99=1) (50 thru 59.99=2) (60 thru 69.99=3) (70 thru 79.99=4) (80 thru 89.99=5) (90 thru highest=6) (sysmis=sysmis) into age_cat.		
exe.		
		
var lab age_cat "Vekove kategorie".		
val lab age_cat		
1 "do 49 let"		
2 "50-59 let"		
3 "60-69 let"		
4 "70-79 let"		
5 "80-89 let"		
6 "nad 90 let".		
*kontrola.		
cro age by age_cat.		
		
*docasny filtr - plati az po prikaz FILTER OFF.		
USE ALL.		
COMPUTE filter_$=(AGE_CAT >=2 AND AGE_CAT <=5).		
VARIABLE LABEL filter_$ 'AGE_CAT >=2 AND AGE_CAT <=5 (FILTER)'.		
VALUE LABELS filter_$ 0 'Not Selected' 1 'Selected'.		
FORMAT filter_$ (f1.0).		
FILTER BY filter_$.		
EXECUTE.		
fre age_cat.		
		
*otestovani vlivu veku (vybrane vekove kategorie 50-89) na vysledky testu pameti (ANOVA).		
ONEWAY recall_2 BY age_cat		
  /STATISTICS DESCRIPTIVES 		
  /MISSING ANALYSIS.		
		
*ostraneni filtru.		
FILTER off.		
use all.		
EXECUTE.		
DELETE VARIABLES filter_$.		
		
		
*8. FINALNI ULOZENI PROMENNE.		
SAVE OUTFILE='C:\SHARE\easySHARE_w4.sav'		
  /COMPRESSED.